Excel Arama İşlevi Nasıl Kullanılır

Bir metin dizesinin veya karakterin konumunu bulmanın yanı sıra Excel’de belirli bir alt dizeyi çıkarmak için ARAMA işlevini nasıl kullanacağınızı bu makalede detaylı olarak anlattık.

Arama işlevi, başka bir dize veya metin içinde belirli bir karakteri veya alt dizeyi arayan ve konumunu döndüren bir metin işlevidir. Başka bir deyişle, bir kelimeyi başka bir kelimenin içinde ve hücredeki konumunu bir tamsayı olarak bulur.

Örneğin, “codetürkiye” kelimesindeki ‘s’ harfinin veya ‘iye’ metninin konumunu bulmak için ARAMA işlevini kullanırsanız, 10 değerini döndürür. aranan hücre

SEARCH işlevi nadiren tek başına kullanılır, genellikle FIND, MID, LEFT, ISNUMBER ve diğerleri ile birlikte kullanılır. Bu yazımızda, ARAMA fonksiyonunun ne olduğunu, nasıl kullanılacağını ve ARA fonksiyonunun Excel’deki diğer fonksiyonlarla birlikte nasıl kullanılacağını anlatacağız.

Excel ARAMA Fonksiyonu

SEARCH işlevi, başka bir metin dizesi içinde bir metin dizesi veya karakter arar ve belirtilen hücrede veya verilen dizede arama dizesinin başlangıç ​​konumunu döndürür.

Excel’de SEARCH işlevinin sözdizimi

=SEARCH (find_text, within_text, [start_num])

• find_text (gerekli) aradığınız karakter veya dize/metindir.
• within_text(gerekli) find_text’i aradığınız yerdir. Aramamız gereken metin dizesini içeren genellikle hücre başvurusudur. Ancak, dizeyi doğrudan formüle de girebilirsiniz.
• [start_num](isteğe bağlı) metin içi dizesinde aramanın başlamasını istediğiniz konumu belirtir. Atlanırsa, arama metin içi dizesinin ilk karakterinden başlar.

SEARCH işlevi büyük/küçük harfe duyarlı değildir. Büyük/küçük harfe duyarlı bir eşleşme arıyorsanız BUL işlevini kullanabilirsiniz. İşlev, arama sözcüğü için birden çok eşleşme bulursa, yalnızca ilk sözcüğün konumunu döndürür.

Arama İşlevi ayrıca aşağıdaki joker karakter operatörlerini de destekler:

• Soru işareti (?)  , herhangi bir tek karakteri veya harfi metin dizesiyle eşleştirmek için kullanılır.
• Yıldız işareti (*)  , herhangi bir sayıda karakteri dizeyle eşleştirmek için kullanılır.
• Tilde (~)   gerçek bir soru işareti veya yıldızla eşleştirmek için kullanılır. Onları bulmak için diğer iki joker karakterden önce bir tilde (~) yazın.

Bir Metin Dizesinde Baştan Bir Karakter veya Metin Arama

SEARCH işlevini, bir metin dizesi içindeki belirli bir karakteri veya metni/kelimeyi en baştan aramak ve konumunu döndürmek için kullanabilirsiniz. Dizeyi hücredeki ilk karakterden soldan sağa, dizenin sonuna kadar arar.

Bir metin dizesinde belirli bir karakteri veya sözcüğü aramak için aşağıdaki formülü deneyin.

=SEARCH("Angeles",A2)

veya

Metin dizesinin başından itibaren arama yapmak için, son argümanı (start_num) atlayabilir veya onu 1 olarak ayarlayabilirsiniz:

=SEARCH("Angeles",A2,1)

Yukarıdaki formül, ‘Los Angeles’ (A2) dizesindeki ilk karakterden başlayarak ‘Angeles’ metnini arar ve aranan metnin (Angeles) – 5 başlangıç ​​noktasının konumunu döndürür.

Formüldeki metin bul bağımsız değişkeni için hücre başvurusunu da kullanabilirsiniz:

=SEARCH(D3,A11,1)

Büyük/küçük harfe duyarsız arama

Daha önce de belirttiğimiz gibi, ARAMA işlevi büyük/küçük harfe duyarlı değildir, formülü kullanarak ‘Tuz’, ‘TUZ’ veya ‘Tuz’ kelimesini arayabilirsiniz ve metin bul veya metin içi argümanları ne olursa olsun aynı sonucu verecektir. kullanır.

Belirli Başlangıç Konumundan Bir Metin Dizesinde Karakter(ler) veya Metin Arama 

SEARCH işlevi, aramayı ilk karakter yerine metin içinde belirli bir noktada başlatarak bir dizedeki bir kelimenin veya metnin konumunu bulmak için de kullanılabilir. Formülde başlangıç ​​numarasını (başlangıç_sayısı) belirterek, aramayı nereden başlatmak istediğinizi fonksiyona söyleyebilirsiniz.

Örnek 1:

Belirli bir konumdan bir kelime aramak için aşağıdaki formülü deneyin:

=SEARCH(C2,A2,9)

Burada, son argümanı (start_num) 9 olarak belirledik. Böylece SEARCH işlevi, A2 hücresinin dizesinde 9. pozisyondan (Hayalet kelimesinden sonraki boşluk karakterinden) Sparta (C2) kelimesini aramaya başlar ve konumunu döndürür. arama kelimesi 14 olarak

Unutmayın, pozisyonları sayarken boşluk karakteri de sayıma dahil edilir.

Aranan Metnin Birden Çok Tekrarı Olduğunda

Başka bir örnek deneyelim. ‘Tanrı’ kelimesinin konumunu bulmak istiyorsak, aşağıdaki formülü deneyebiliriz:

=SEARCH(C2,A3,2)

Burada başlangıç ​​numarası (start_num) 2’dir, bu nedenle arama ‘y’ karakterinden başlar. Dizede ‘Tanrı’ kelimesinin iki örneği olmasına rağmen, yalnızca başlangıç ​​sayısından ilk kelimenin konumunu döndürür. Bu nedenle, çıktı 4’tür.

Şimdi, başlangıç ​​numarasını 5 olarak değiştirmeyi deneyelim:

=SEARCH(C2,A3,5)

Şimdi, çıktıyı 9 olarak alacaksınız, çünkü arama ‘o’ karakterinden (Tanrı kelimesinin ilk örneğinde) başlar ve ‘Tanrı’nın ilk örneği yok sayılır.

#DEĞER! hata 

‘#DEĞER!’ alacağınız iki durum vardır. SEARCH işleviyle metin ararken hata oluştu:

• Belirtilen arama sözcüğü (bul_metin) belirtilen metin içi dizesinde bulunamazsa.
• Başlangıç ​​numarası (başlangıç_sayısı) sıfırdan küçük veya metin içi dizenin uzunluğundan büyükse.

Aşağıda görebileceğiniz gibi, arama için başlangıç ​​sayısı 10’dur. ‘Tanrı’ kelimesinin tam kelimesinin her iki örneği de 10. pozisyondan önce gelir, dolayısıyla #DEĞER! hata.

Aşağıdaki örnekte, başlangıç ​​sayısı metin içi dizenin uzunluğunu aşıyor, bu nedenle #DEĞER! hata.

SEARCH işlevi, her türlü karakteri, hatta sembolleri bulmak için kullanılabilir. Örneğin, verilen dizede Ticari Marka (™) sembolünün yerini aradık ve konumunu 20 olarak bulduk.

Excel ARAMA işlevinde Joker Karakterlerle Arama

SEARCH işlevi joker karakterleri destekler – soru işareti (?), yıldız işareti (*) ve yaklaşık işareti (~). Soru işareti (?) herhangi bir tek karakteri temsil eder, yıldız işareti (*) herhangi bir karakter dizisini belirtir ve tilde (~) diğer iki joker karakterden herhangi biriyle eşleşir.

Örnek 1:

Aşağıdaki örnekte, A13 hücresindeki dizede ‘Kalemler’ (Kalem*S) kelimesinin konumunu bulmak için joker karakter (*) kullanılmıştır:

=SEARCH(D9,A13,1)

Burada arama sözcüğü ‘Kalem*ler’dir (D9), bu nedenle formül, A13 hücresinde ‘Kalem’ ile başlayan ve ‘s’ ile biten ve aralarında herhangi bir sayıda karakter bulunan herhangi bir metni arar. ‘Kalemler’ metniyle eşleşir ve konumunu 12 olarak döndürür.

Örnek 2:

Başlangıç ​​numarasını (start_num) belirlerken, aramaya başlamak için doğru başlangıç ​​numarasını belirtmeniz gerekir.

Örneğin, aşağıdaki formül, A10 hücresinin dizesindeki ‘c*r’ metninin konumunu bulabilir:

=SEARCH(C2,A10,1)

‘Character’ kelimesindeki ‘char’ın konumunu bulmak istedik, bunun yerine ‘Wildcard’daki ‘car’ın konumunu 5 olan bulduk.

Bunu düzeltmek için, aramanın başlangıç ​​numarasını 8 olarak değiştirebiliriz. Şimdi işlev, aramayı jokerin sonundaki ‘d’ karakterinden başlatır ve ‘Karakterler’de ‘Karakter’in konumunu bulur.

Örnek 3:

Arama kelimesinden önce joker karakterin kullanıldığı başka bir örnek. Şimdi A3 hücresindeki ‘savaş’ın önünde kaç karakter olursa olsun, arama konumunu 1 olarak döndürecektir.

Örnek 4 :

Aşağıdaki örnekte, A12 hücresindeki dizedeki ‘PC940’ (?C94?) metninin konumunu bulmak için soru (?) kullanılmıştır:

=SEARCH("?C94?",A12,1)

Burada ?herhangi bir tek karakter belirtilir, bu nedenle formül, 7 konumunda bulunan ‘PC940’ dizesiyle eşleşir.

SEARCH İşlevini Diğer İşlevlerle Kullanma

SEARCH işlevi, güçlü hesaplamalar yapmak için genellikle MID, LEFT, RIGHT veya ISNUMBER gibi diğer işlevlerle birleştirilir.

SEARCH İşlevini Kullanarak Dizeyi Bulun ve Çıkarın

Belirli bir karakterin solunda veya sağında veya iki karakter arasında bir metin dizesindeki bir alt dizeyi bulmak ve ayıklamak için SOL, SAĞ veya ORTA işlevleriyle ARAMA işlevini kullanabilirsiniz. Örneğin, bu kombinasyonlar bir tam ad listesini ilk adlara, soyadlara ve ikinci adlara bölmek için yararlıdır.

SEARCH ve LEFT fonksiyonlarını kullanarak Belirli Karakter(ler)den Önce Bir Alt Dizgiyi Çıkarın

Bir metin dizeniz veya dize listeniz varsa, bir alt dizeyi veya dizenin bir kısmını ayrı bir sütuna çıkarmak için SOL işleviyle birlikte SEARCH işlevini kullanabilirsiniz.

SOL işlevi, dizenin ilk karakterinden başlayarak, dizenin sol tarafından belirli sayıda karakter çıkarmanıza yardımcı olur.

LEFT işlevinin sözdizimi:

=LEFT(text,[num_chars])

İki argüman gerektirir:

• textçıkarmak istediğiniz karakterleri içeren bir hücreye yapılan metin dizesi veya başvurusudur.
• num_charsverilenlerde soldan sağa çıkarmak istediğiniz karakter sayısıdır (karakterler textarasındaki boşluk buna dahildir).

Bir sütunda tam adların bir listesinin olduğunu ve Adları ayrı sütunlara çıkarmak istediğinizi varsayalım, bunu UZUNLUK ve ARAMA işlevleriyle yapabilirsiniz. İşte nasıl çalıştığı:

Belirli bir karakterden önce bir alt dizeyi çıkarmak için kullanılan sözdizimi :

Belirli bir karakterden önce bir alt dize çıkarmak için aşağıdaki formülü (LEN ve BUL kombinasyonu) kullanın:

=LEFT(text,SEARCH("char",text)-1)

• textiçinden bir alt dize/metin çıkarmak istediğimiz metin dizesini belirtir. Bir metin dizesi veya dizeye sahip bir hücreye başvuru olabilir.
• charkonumu belirlemek istediğimiz özel karakterdir. 

SEARCH işlevi, verilen metin dizesinde belirtilen karakterin konumunu bulur, ardından çıkarılacak alt dizenin uzunluğunu belirlemek için bu konum numarasından (belirtilen karakterin konumu) 1 çıkarılır. Ardından, dizede soldan sağa karakter sayısını çıkarmak için uzunluk SOL’a verilir.

Örnek:

İlk adı tam addan çıkarmak için aşağıdaki formülü girin:

=LEFT(A2,SEARCH(" ",A2)-1)

Yukarıdaki formül, boşluk karakterinin (” “) konumunu (7 olan) belirlemek için SEARCH işlevini kullanır ve boşluğun kendisini hariç tutmak için 1 çıkarır. Şimdi ilk adın uzunluğunu aldık (en soldaki 6 karakter). Bu sayı daha sonra dizide soldan sağa karakter sayısını (6) döndürmek için LEFT işlevine verilir.

Dize listenizde, aralarında boşluk karakterleri olduğu gibi bir desen varsa. charArdından , her formül için bağımsız değişken belirtmek zorunda kalmadan otomatik doldurmayı kullanarak tüm sütundan dizeleri çıkarmak için Excel SOL ve BUL formüllerini kullanabilirsiniz .

Bunu yapmak için formül hücresini (B2) seçin ve bu formülü bir sütuna uygulamak için doldurma tutamacını (seçilen hücrenin altındaki küçük yeşil kare) diğer hücrelere sürükleyin. Şimdi tüm ilk isimler aşağıda gösterildiği gibi B sütununa alındı:

SEARCH ve RIGHT kullanarak Belirli Karakter(ler)den Sonra Bir Alt Dize Ayıklayın

Belirli bir karakterden sonra bir alt dize çıkarmak istiyorsanız, SAĞ, ARAMA ve UZUNLUK işlevlerinin birleşimini kullanmanız gerekir. SEARCH ve UZUNLUK işlevi, ayıklanacak karakter sayısını bulmak için SAĞ işlevinin num_char bağımsız değişkeninde yuvalanır ve SAĞ işlevi bu karakterleri çıkarır.

Belirli bir karakterden sonra bir alt dize çıkarmak için kullanılan sözdizimi :

=RIGHT(text,LEN(text)-SEARCH("char",text))

Tam adlardan oluşan bir sütunumuz olduğunu ve Soyadlarını ayrı sütunlara çıkarmak istediğinizi varsayalım, bunu aşağıdaki formülle yapabilirsiniz:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Yukarıdaki formülde, SEARCH işlevi ‘ ‘ boşluk karakterinin 7 olan konumunu döndürür ve UZUNLUK işlevi dizgideki toplam karakter sayısını (dize uzunluğu) bulur. Ardından, dizenin sonundan bu kadar çok karakteri çıkarmak için SAĞ işlevine sağlanan soyadının uzunluğunu bulmak için boşluğun konumu dizedeki toplam karakter sayısından çıkarılır.

Soyadı ayrı bir sütuna çıkarıldıktan sonra, bu formülü sütuna uygulamak için doldurma tutamacını diğer hücrelere sürükleyin. Şimdi tüm soyadlar aşağıda gösterildiği gibi C sütununa alındı:

MID ve SEARCH İşlevini kullanarak İki Karakter Arasında Bir Alt Dize Ayıklayın

Metin dizesinin orta kısmını çıkarmak isterseniz, bunu MID ve SEARCH fonksiyonlarının yardımıyla yapabilirsiniz.

Excel ORTA İşlevi

MID Excel İşlevi, bir dizenin orta bölümünü çıkarmak için kullanılır. Bunu yapmak için metin dizesi, bir başlangıç ​​noktası (konum) ve ayıklanacak karakter sayısı gerekir.

Sözdizimi:

=MID(text,start_num,num_chars)

• textiçinden bir alt dize/metin çıkarmak istediğimiz metin dizesini belirtir. Bir metin dizesi veya dizeye sahip bir hücreye başvuru olabilir.
• start_nummetin dizesindeki ayıklamayı başlatmak istediğiniz konumu belirtir. Atlanırsa, arama metin içi dizesinin ilk karakterinden başlar.
• num_charsverilen içinde soldan sağa çıkarmak istediğiniz karakter sayısıdır text.

start_num ve num_chars bağımsız değişkenleri, iki karakter arasında bir alt dize çıkarmak için MID işlevine SEARCH işlevi tarafından sağlanabilir.

Bu basit örnekle MID fonksiyonunun nasıl çalıştığını görelim:

=MID(A2,10,4)

Formül, A2 hücresindeki karakterleri 10. karaktere ulaşana kadar soldan sağa sayar ve ardından sonraki 7 karakteri (10. karakter dahil) döndürür.

MID ve SEARCH ile iki karakter arasında bir alt dize çıkarmak için aşağıdaki sözdizimini kullanın:

=MID(text,SEARCH("char",text)+1,SEARCH("char",text)-SEARCH("char",text)-1)

• text: Bir alt dizeyi çıkarmak istediğimiz bir dize, bu bir metin dizesi veya dizesi olan bir hücreye başvuru olabilir.
• char: Konumunu belirlemek istediğimiz belirli bir karakter. 

Örnek 1:

Ürün Kimlikleri sütununda olduğunuzu ve ‘-‘ ve ‘/’ karakterleri arasındaki kimlik numaralarını çıkarmak istediğinizi varsayalım.

Belirtilen iki karakterin konumlarını bulmamız, ardından verilen 2. karakterin konumunu 1. karakterin konumundan çıkarmamız ve ilk karakterin konumundan başlayarak kaç karakter çıkaracağımızı belirlemek için sonuçtan 1 çıkarmamız gerekir.

İki karakter arasındaki orta dizeyi çıkarmak için bu formülü boş bir hücreye girin:

=MID(A2,SEARCH("-",A2)+1,SEARCH("/",A2)-SEARCH("-",A2)-1)

Açıklama:

• A2 alt dizeyi çıkarmak istediğimiz orijinal metin dizesini içeren hücredir.
• SEARCH("-",A2)+1(start_num) belirtilen ilk karakterin (-) konumunu belirler ve sonraki karakterden çıkarmayı başlatmak için 1 ekler (start_num=5).
• SEARCH("/",A2)-SEARCH("-",A2)-1(num_chars), ‘/’ (13) konumunu ‘-‘ (4) konumundan ve sonuçtan 1 çıkararak ‘-‘ ve ‘/’ karakterleri arasında çıkarmak istediğimiz alt dizenin uzunluğunu bulur. Bu, MID işlevine kaç karakter çıkarılacağını söyleyecektir.

Artık MID işlevi, dizeden kaç karakter çıkaracağını ve nereden başlayacağını biliyor. C2 hücresindeki orta dizeyi döndürür.

Bundan sonra, tüm sütun için orta dizeyi çıkarmak için formülü hücrelerin geri kalanına kopyalayabilirsiniz.

Örnek 2 :

MID ve SEARCH, tam adlar listesinden ikinci adları çıkarırken gerçekten kullanışlıdır. Orta adı çıkarmak için şu formülü kullanın:

=MID(A2,SEARCH(" ",A2)+1,SEARCH(" ",A2,SEARCH(" ",A2)+1)-SEARCH(" ",A2)-1)

Sorun, belirtilen karakterlerin her ikisinin de boşluk karakterleri (aynı) olmasıdır, bu nedenle formül hangisinin hangisi olduğunu ayırt edemez ve #DEĞER! ile sonuçlanır. Bunu düzeltmek için, bir SEARCH fonksiyonunu başka bir SEARCH fonksiyonunun içine yerleştirdik ve ikinci boşluk karakterinin konumunu bulmak için ‘num_chars’ argümanına 1 ekledik.

• SEARCH(" ",A2)+1ilk boşluk karakterinin konumuna 1 ekleyerek çıkarma için başlangıç ​​noktasını belirler.
• SEARCH(" ",A2,SEARCH(" ",A2)+1)-SEARCH(" ",A2)-12. boşluğun konumunu 1. boşluğun konumundan çıkarır ve sonuçtan 1 çıkarır, sondaki boşluğu kaldırmak için. Ortaya çıkan değer, formüle kaç karakter çıkarılacağını söyler.

Şimdi orijinal metin dizesi, başlangıç ​​numarası ve karakter sayısı ile MID işlevi, tam addan (A2) ikinci adı çıkarır.

SEARCH işlevini kullanarak bir Dizedeki Bir Karakterin N. Oluşumunu veya Konumunu Bulun

Bir dizede birden çok kez geçen bir karakterin veya metnin konumunu bulmaya çalışıyorsanız, SEARCH işlevi yalnızca o karakterin/metnin ilk eşleşmesini döndürür. Ancak, ARAMA ve DEĞİŞTİR işlevlerini birleştirdiğinizde, bir metin dizesindeki belirli bir karakterin (veya karakter dizesinin) n. oluşumunu veya konumunu (ikinci veya üçüncü örnek gibi) kolayca bulabilirsiniz.

Bir karakterin N’inci oluşumunun konumunu bulmak için genel formül:

=SEARCH(CHAR,SUBSTITUTE(text, character, CHAR, [instance_num])) 

nerede

• CHARASCII koduna göre bir sembol döndüren bir fonksiyondur. Dizede görünmeyeceğinden emin olduğunuz herhangi bir ASCII kodunu veya sembolü kullanabilirsiniz.
• textn’inci oluşumunu bulmak istediğiniz dizeyi içeren bir hücreye yapılan metin dizesi veya başvurusudur.
• character n’inci oluşumunu bulmak istediğiniz karakterdir.
• [instance_num] karakter(ler)in veya metin dizesinin hangi oluşumunu bulmak istediğinizi belirtir.

Örnek 1:

Aşağıdaki örnekte, ‘/’ karakterinin 2. oluşumunu aşağıdaki formülle bulmak istiyoruz:

=SEARCH("$",SUBSTITUTE(A1,"/","$",2))

SUBSTITUTE işlevi aslında bir karakter veya metin arar ve onu bir başkasıyla değiştirir. Yukarıdaki formülde, (/) karakterini dizede görünmeyecek olan ‘$’ ile değiştiriyoruz. Dolayısıyla SUBSTITUTE işlevi, ‘$’ sembolü için dizgede ‘/’ karakterinin ^2. oluşumunu değiştirdiğinde, SEARCH o karakterin konumunu döndürür.

CHARAynı sonuçları elde etmek için arama karakterlerini (/) değiştirmek için formülün bağımsız değişkeninde CHAR ASCII kodunu da kullanabilirsiniz .

Örnek 2:

Metin dizesinden belirli bir karakterin n’inci oluşumunu bulmanıza yardımcı olabilecek başka bir formül.

Aşağıdaki formül, A1 hücresinde “e”nin 3. oluşumunun konumunu döndürür:

=SEARCH("e",A13,SEARCH("e",A13)+2)

Yukarıdaki formül, 3. ‘e’ konumunu 23 olarak döndürür. Son argümanı (2) buna göre değiştirerek formüldeki oluşumu belirtebilirsiniz. “e”nin ilk oluşumunu bulmak istiyorsanız, 2’yi 0 olarak değiştirin. “e”nin ikinci oluşumunu bulmak için 2’yi 1’e değiştirin ve bu şekilde devam edin.

Belirli Metni Kontrol Etmek için ISNUMBER ile SEARCH  işlevini  birleştirin

Bildiğimiz gibi, SEARCH işlevi bir dizge içinde belirli bir alt dizgiyi arar ve metin bulunursa sayısal konumunu döndürür, aksi takdirde bir #DEĞER! hata. ISNUMBER işlevi, bir hücrenin sayı içerip içermediğini kontrol eder. Evet ise DOĞRU, aksi halde YANLIŞ döndürür.

Ancak ISNUMBER işlevi ARAMA işleviyle birleştiğinde, bir hücrenin belirli bir metin içerip içermediğini kontrol edebilir ve metin bulunursa DOĞRU, aksi takdirde YANLIŞ döndürür.

Bir hücrenin belirli metni içerip içermediğini kontrol etmek için genel formül:

=ISNUMBER(SEARCH(substring,text))

Neresi

• substring bulmak istediğiniz metin dizesidir
• text alt dizeyi kontrol etmek istediğiniz hücre veya dizedir.

Örnek:

Aşağıdaki veri kümesinde, A sütununda İnek kelimesinin bulunup bulunmadığını bulmak istiyoruz:

=ISNUMBER(SEARCH("Cow",A2))

İlk önce formülü A2 hücresine girin ve formülü sütuna otomatik olarak doldurun. ISNUMBER işlevi, ‘İnek’ dizesinin A2 hücresinde görünüp görünmediğini kontrol eder ve YANLIŞ döndürür.

SEARCH işlevi, A2 hücresinde ‘İnek’ metni olup olmadığını kontrol eder ve ‘#DEĞER!’ değerini döndürür. hata (çünkü İnek metni mevcut değil). Değer!’ bir sayı olmadığı için ISNUMBER işlevi ‘YANLIŞ’ değerini döndürür. B2 hücresinde, SEARCH işlevi ‘İnek’ kelimesini kontrol eder ve pozisyon numarasını döndürür, böylece ISNUMBER ‘TRUE’ değerini döndürür.

Formüle dize girmek için bir hücre referansı da kullanabiliriz:

=ISNUMBER(SEARCH(B$1,A2))

IF, ISNUMBER ve SEARCH işleviyle Belirli Metni kontrol edin

Bir dizede bir alt dize bulunduğunda DOĞRU veya YANLIŞ dışında bir şey almak istiyorsanız, ISNUMBER ve SEARCH ile EĞER işlevini kullanabilirsiniz.

Örneğin, A sütunundaki her hücrenin ‘İnek’ kelimesini içerip içermediğini bulmaya çalışacağız ve bir hücre bu metni içeriyorsa “Bulundu”, değilse “Bulunamadı” sonucunu döndüreceğiz:

=IF(ISNUMBER(SEARCH(B$1,A2)), "Found","Not Found")

Doldurma tutamacını kullanarak B2 hücresindeki formülü hücrelerin geri kalanına kopyalayabilirsiniz. Formülde, ARAMA işlevi B1’deki değeri A1 hücresine göre kontrol eder ve bir hata döndürür. Bu nedenle ISNUMBER işlevi YANLIŞ döndürür. Sonuç olarak, EĞER işlevi ‘Bulunamadı’ değerini döndürür.